[overload125]

Ich habe gestern Windows 8 Pro als Upgrade von Windows 7 installiert und heute beim Testen unter Everest Ultimate festgestellt, dass dort unter "Betriebssystem" ein anderer Produktschlüssel angezeigt wird, als der bei der Installation eingegebene. Produkt ID ist mit der in der Basisinformation identisch. Kann das jemand anderes auch bei seiner Installation bestätigen?

[slurp]

Die Produkt-ID ist nicht identlisch mit dem Produktschlüssel, sondern wird aus Schlüssel und Hashwert von versch. Hardwaredaten errechnet. Das war schon mind. zu Vista-Zeiten so..

Dieser Beitrag wurde von slurp bearbeitet: 27. Oktober 2012 - 18:18

[overload125]

Das ist schon klar. Everest zeigt aber einen anderen Produktschlüssel an, d.h. es ist nicht der von mir bei der Installation eingegebene.

[mezo]

Zitat (overload125: 27. Oktober 2012 - 18:19)

Das ist schon klar. Everest zeigt aber einen anderen Produktschlüssel an, d.h. es ist nicht der von mir bei der Installation eingegebene.

hast du den wenigstens die 2 ids mal verglichen

[overload125]

Ja, habe ich ja schon oben geschrieben, die ID's sind identisch, die Produktschlüssel nicht!!

[Windows 8 User]

Ist der Produktkey villeicht der von Windows 7?

[overload125]

Negativ!

[NiFu]

Zitat (overload125: 27. Oktober 2012 - 18:12)

beim Testen unter Everest Ultimate festgestellt, dass dort unter "Betriebssystem" ein anderer Produktschlüssel angezeigt wird

Es kann vielleicht sein, dass "Everest" noch die alte Schlüssel-Auslese-Methode verwendet, die noch unter Windows 7 funktioniert, aber unter Windows 8 nicht mehr.

Speichere das folgende mal als Text-Datei mit der Endung "*.vbs" ab und starte das VBS-Script per Doppelklick - da sollte dann der richtige Key angezeigt werden:

Set WshShell = CreateObject("WScript.Shell")
Key = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
DigitalID = WshShell.RegRead(key & "DigitalProductId")

ProductName = "Product Name: " & WshShell.RegRead(Key & "ProductName") & vbNewLine
ProductID = "Product ID: " & WshShell.RegRead(Key & "ProductID") & vbNewLine
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductID = ProductName & ProductID & ProductKey

If vbYes = MsgBox(ProductId & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "Windows Key Information") then
   Save ProductID
End if

Function ConvertToKey(Key)
    Const KeyOffset = 52
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Chars = "BCDFGHJKMPQRTVWXY2346789"
    Do
        Cur = 0
        X = 14
        Do
            Cur = Cur * 256
            Cur = Key(X + KeyOffset) + Cur
            Key(X + KeyOffset) = (Cur \ 24)
            Cur = Cur Mod 24
            X = X -1
        Loop While X >= 0
        i = i -1
        KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
        Last = Cur
    Loop While i >= 0
    If (isWin8 = 1) Then
        keypart1 = Mid(KeyOutput, 2, Last)
        insert = "N"
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then KeyOutput = insert & KeyOutput
    End If
    a = Mid(KeyOutput, 1, 5)
    b = Mid(KeyOutput, 6, 5)
    c = Mid(KeyOutput, 11, 5)
    d = Mid(KeyOutput, 16, 5)
    e = Mid(KeyOutput, 21, 5)
    ConvertToKey = a & "-" & b & "-" & c & "-" & d & "-" & e
End Function

Function Save(Data)
    Const ForWRITING = 2
    Const asASCII = 0
    Dim fso, f, fName, ts
    fName = "Windows Key.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    fso.CreateTextFile fName
    Set f = fso.GetFile(fName)
    Set f = f.OpenAsTextStream(ForWRITING, asASCII)
    f.Writeline Data
    f.Close
End Function

[overload125]

Danke für das Script. Es zeigt tatsächlich den ursprünglichen Produktschlüssel, es liegt wohl in der Tat an Everest.

[DON666]

Wenn man übrigens das Media Center freigeschaltet hat, nennt sich das OS danach "Windows 8 Pro with Media Center", und es wird dann auch der Media-Center-Key als Product Key fürs System angezeigt.