[laser2011]

Vieleicht hat ja jemand ahnung.

und zwar nutze ich folgende Makro:

Zitat

"Private Sub Worksheet_Change(ByVal Target As Range)
Dim loZeile As Long
If Target.Address = "$C$3" Then
Application.ScreenUpdating = False
ActiveSheet.UsedRange.Rows.Hidden = False
If Target <> "" Then
For loZeile = ActiveSheet.UsedRange.SpecialCells(xlCellTypeLastCell).Row To 4 Step -1
Cells(loZeile, 1).EntireRow.Hidden = Application.CountIf(Rows(loZeile), Target) = 0
Next loZeile
End If
Application.ScreenUpdating = True
End If
End Sub"

das geht auch soweit.

allerdings muß ich in das suchfeld genau das eingeben was auch in der Tabelle steht.

Ich möchte aber auch gerne das alle ähnlichen angezeigt werden.

zb. Gesucht wird nach "carly"

dann soll auch "Carly Rae Jepsen" angezeigt werden.

was muß ich dafür ändern?

Vielen Dank

Dieser Beitrag wurde von laser2011 bearbeitet: 30. Mai 2013 - 14:23

[Sturmovik]

Nur mal zum verständnis: C3 ist eine Art Suchfeld und sobald da was eingegeben wird, soll in einer Liste gesucht werden was dem eintrag in C3 entspricht?

[laser2011]

Hallo,

Ja genau.

das geht auch.
allerdings nur wenn ich es genau so eingeben wie es auch in der Liste geschrieben ist

Ich kenne diese beiden befehle:
aber bekomme sie nicht unter

Zitat

Der Titel muss auf das Zeichen genau übereinstimmen, sonst wird "Nein" ausgegeben.
Für Teiltreffer müsstest LookAt:=xlPart nutzen

[Sturmovik]

Ich werd grad aus dieser Anweisung nicht schlau

Cells(loZeile, 1).EntireRow.Hidden = Application.CountIf(Rows(loZeile), Target) = 0

Aber wenn Lookat:=xlpart irgendwo reinmuss dann hinter target
Woanders ergibt das keinen Sinn.

Edit: grade mal getestet, die zählenwenn funktion unterstützt garkeine unscharfen Treffer

Dieser Beitrag wurde von Sturmovik bearbeitet: 30. Mai 2013 - 14:38

[laser2011]

Ich glaube "Lookat:=xlpart" ist für diese Anweisung nicht geeignet..


also muß ich es komplett neu machen...

oh mann ich kenne mich mit den Makros nicht wirklich gut aus.

hast du ein Vorschlag..

[Sturmovik]

Ja habe ich. Schön ist anders, aber bei meinem Musikverzeichnis funktionierts:

If InStr(1, StrConv(Cells(loZeile, 1), vbLowerCase), StrConv(Target, vbLowerCase)) = 0 Then Cells(loZeile, 1).EntireRow.Hidden = True

Dieser Beitrag wurde von Sturmovik bearbeitet: 30. Mai 2013 - 14:54

[laser2011]

mhh,
das geht nicht..

hier mal meine datei
(habe ich weg gemacht)

das geht eigentlich sehr gut.

was halt noch fehlt ist das suchen nach "unscharfen Treffer "

Dieser Beitrag wurde von laser2011 bearbeitet: 30. Mai 2013 - 15:31

[Sturmovik]

Witzbold, ohne Inhalt kann ich das schlecht testen.

Aber ich glaube ich weiß wo der Fehler ist.
In welchen Spalten soll von c3 aus gesucht werden? nur in Spalte c?
Wenn das so ist, dann

If InStr(1, StrConv(Cells(loZeile, 3), vbLowerCase), StrConv(Target, vbLowerCase)) = 0 Then Cells(loZeile, 1).EntireRow.Hidden = True

Wenn mehrere Spalten durchsucht werden sollen, dann muss ich mir noch was anderes überlegen. Da wäre auch die find-Methode besser geeignet.

EDIT: Code falsch geändert, jetzt solltes passen

Dieser Beitrag wurde von Sturmovik bearbeitet: 30. Mai 2013 - 15:06

[laser2011]

Nein es soll in allen spalten gesucht werden.

und dann auch nur die angezeigt werden die gefunden wurden.

habe ja niccht alles raus gelöscht.

die ersten 2 Spalten sind noch mit inhalt.


mhh dann bleibe ich bei meinem.
wenn ich ein Sternchen dahinter mache geht es.

wollte halt nur darauf verzichten...

[Sturmovik]

Ok, dann wirds wohl eher was mit range.find
Kleinen Moment bitte

---

Bitte mal ausprobieren:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim loZeile As Long, found As Range
    If Target.Address = "$C$3" Then
        Application.ScreenUpdating = False
        ActiveSheet.UsedRange.Rows.Hidden = False
        If Target <> "" Then
            For loZeile = ActiveSheet.UsedRange.SpecialCells(xlCellTypeLastCell).Row To 4 Step -1
                
                Set found = Nothing
                Set found = Cells(loZeile, 1).EntireRow.Find(what:=Target, lookat:=xlPart)
                If found Is Nothing Then Cells(loZeile, 1).EntireRow.Hidden = True
            Next loZeile
        End If
        Application.ScreenUpdating = True
    End If
End Sub

Dieser Beitrag wurde von Sturmovik bearbeitet: 30. Mai 2013 - 15:18

[laser2011]

Jey.

Super.

Vielen Vielen Dank

Das ist genau das..
warum bin ich nicht schon vorher hierher gekommen..
seit 4 Stunden versuche ich zu basteln :-)

Danke nochmal